Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
kernel
os
linux
1/*
2 * Common module linker script, always used when linking a module.
3 * Archs are free to supply their own linker scripts. ld will
4 * combine them automatically.
5 */
6#ifdef CONFIG_UNWIND_TABLES
7#define DISCARD_EH_FRAME
8#else
9#define DISCARD_EH_FRAME *(.eh_frame)
10#endif
11
12#include <asm-generic/codetag.lds.h>
13
14SECTIONS {
15 /DISCARD/ : {
16 *(.discard)
17 *(.discard.*)
18 *(.export_symbol)
19 *(.no_trim_symbol)
20 }
21
22 __ksymtab 0 : ALIGN(8) { *(SORT(___ksymtab+*)) }
23 __kcrctab 0 : ALIGN(4) { *(SORT(___kcrctab+*)) }
24 __kflagstab 0 : ALIGN(1) { *(SORT(___kflagstab+*)) }
25
26 .ctors 0 : ALIGN(8) { *(SORT(.ctors.*)) *(.ctors) }
27 .init_array 0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
28
29 .altinstructions 0 : ALIGN(8) { KEEP(*(.altinstructions)) }
30 __bug_table 0 : ALIGN(8) { KEEP(*(__bug_table)) }
31 __jump_table 0 : ALIGN(8) { KEEP(*(__jump_table)) }
32 __ex_table 0 : ALIGN(4) { KEEP(*(__ex_table)) }
33
34 __patchable_function_entries 0 : { *(__patchable_function_entries) }
35
36 .init.klp_funcs 0 : ALIGN(8) { KEEP(*(.init.klp_funcs)) }
37 .init.klp_objects 0 : ALIGN(8) { KEEP(*(.init.klp_objects)) }
38
39#ifdef CONFIG_ARCH_USES_CFI_TRAPS
40 __kcfi_traps 0 : { KEEP(*(.kcfi_traps)) }
41#endif
42
43#ifndef CONFIG_ARCH_WANTS_MODULES_TEXT_SECTIONS
44 .text 0 : {
45 *(.text .text.[0-9a-zA-Z_]*)
46 }
47#endif
48
49 .bss 0 : {
50 *(.bss .bss.[0-9a-zA-Z_]*)
51 *(.bss..L*)
52 }
53
54 .data 0 : {
55 *(.data .data.[0-9a-zA-Z_]*)
56 *(.data..L*)
57 }
58
59 .rodata 0 : {
60 *(.rodata .rodata.[0-9a-zA-Z_]*)
61 *(.rodata..L*)
62 }
63
64 MOD_SEPARATE_CODETAG_SECTIONS()
65}
66
67/* bring in arch-specific sections */
68#include <asm/module.lds.h>