Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
kernel
os
linux
1#!/usr/bin/awk -f
2# SPDX-License-Identifier: GPL-2.0
3# Before running this script please ensure that your PATH is
4# typical as you use for compilation/installation. I use
5# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
6# differ on your system.
7
8BEGIN {
9 usage = "If some fields are empty or look unusual you may have an old version.\n"
10 usage = usage "Compare to the current minimal requirements in Documentation/process/changes.rst\n"
11 print usage
12
13 system("uname -a")
14 printf("\n")
15
16 vernum = "[0-9]+([.]?[0-9]+)+"
17 libc = "libc[.]so[.][0-9]+$"
18 libcpp = "(libg|stdc)[+]+[.]so([.][0-9]+)+$"
19
20 printversion("bash", version("bash --version"))
21 printversion("bc", version("bc --version"))
22 printversion("bindgen", version("bindgen --version"))
23 printversion("binutils", version("ld -v"))
24 printversion("bison", version("bison --version"))
25 printversion("btrfs-progs", version("btrfs --version"))
26 printversion("Clang", version("clang --version"))
27 printversion("Console-tools", version("loadkeys -V"))
28 printversion("Dynamic linker (ldd)", version("ldd --version"))
29 printversion("e2fsprogs", version("e2fsck -V"))
30 printversion("flex", version("flex --version"))
31 printversion("gdb", version("gdb -version"))
32 printversion("GNU awk", version("gawk --version"))
33 printversion("GNU C", version("gcc -dumpversion"))
34 printversion("GNU make", version("make --version"))
35 printversion("GNU tar", version("tar --version"))
36 printversion("GRUB2", version("grub2-install --version"))
37 printversion("GRUB", version("grub-install --version"))
38 printversion("gtags", version("gtags --version"))
39 printversion("iptables", version("iptables -V"))
40 printversion("Isdn4k-utils", version("isdnctrl"))
41 printversion("jfsutils", version("fsck.jfs -V"))
42 printversion("Kbd", version("loadkeys -V"))
43 printversion("kmod", version("kmod -V"))
44
45 while ("ldconfig -p 2>/dev/null" | getline > 0)
46 if ($NF ~ libc || $NF ~ libcpp)
47 if (!seen[ver = version("readlink " $NF)]++)
48 printversion("Linux C" ($NF ~ libcpp? "++" : "") " Library", ver)
49
50 printversion("mcelog", version("mcelog --version"))
51 printversion("mkimage", version("mkimage --version"))
52 printversion("Module-init-tools", version("depmod -V"))
53 printversion("Mount", version("mount --version"))
54 printversion("Net-tools", version("ifconfig --version"))
55 printversion("nfs-utils", version("showmount --version"))
56 printversion("openssl", version("openssl version"))
57 printversion("pahole", version("pahole --version"))
58 printversion("Pcmcia-cs", version("cardmgr -V"))
59 printversion("pcmciautils", version("pccardctl -V"))
60 printversion("PPP", version("pppd --version"))
61 printversion("procps", version("ps --version"))
62 printversion("Python", version("python3 -V"))
63 printversion("quota-tools", version("quota -V"))
64 printversion("Rust", version("rustc --version"))
65 printversion("Sh-utils", version("expr --v"))
66 printversion("Sphinx", version("sphinx-build --version"))
67 printversion("squashfs-tools", version("mksquashfs -version"))
68 printversion("udev", version("udevadm --version"))
69 printversion("util-linux", version("mount --version"))
70 printversion("Wireless-tools", version("iwconfig --version"))
71 printversion("xfsprogs", version("xfs_db -V"))
72
73 while ("sort /proc/modules" | getline > 0) {
74 mods = mods sep $1
75 sep = " "
76 }
77 printversion("Modules Loaded", mods)
78}
79
80function version(cmd, ver) {
81 cmd = cmd " 2>&1"
82 while (cmd | getline > 0) {
83 if (match($0, vernum)) {
84 ver = substr($0, RSTART, RLENGTH)
85 break
86 }
87 }
88 close(cmd)
89 return ver
90}
91
92function printversion(name, value, ofmt) {
93 if (value != "") {
94 ofmt = "%-20s\t%s\n"
95 printf(ofmt, name, value)
96 }
97}